엑셀 SUMIFS·COUNTIFS 함수 사용법｜여러 조건으로 합계와 개수 구하기

엑셀에서 조건에 맞는 합계나 개수를 구할 때 SUMIF와 COUNTIF 함수를 사용할 수 있습니다.

하지만 실제 업무에서는 한 가지 조건만으로 원하는 데이터를 구분하기 어려운 경우가 많습니다.

예를 들면 다음과 같습니다.

• A팀이면서 진행 상태가 ‘완료’인 주문 금액
• 제품 A이면서 처리가 완료된 업무 건수
• 제품 B이면서 주문 금액이 100만 원 이상인 건수
• 지정한 시작일부터 종료일까지 발생한 주문 금액

이처럼 조건을 두 개 이상 적용해야 할 때 사용하는 함수가 SUMIFS와 COUNTIFS입니다.

SUMIFS는 여러 조건을 모두 만족하는 값의 합계를 구하고, COUNTIFS는 여러 조건을 모두 만족하는 셀의 개수를 구합니다.

이번 글에서는 SUMIFS와 COUNTIFS의 기본 구조부터 문자·숫자·날짜 조건, 조건을 셀에서 가져오는 방법과 자주 발생하는 오류까지 알아보겠습니다.

※ 이 글은 Excel 2016을 기준으로 작성했으며, Microsoft 365를 비롯한 이후 버전에서도 같은 방식으로 사용할 수 있습니다.

SUMIF와 COUNTIF의 기본 사용법이 궁금하다면 이전 글인 ‘엑셀 SUMIF·COUNTIF 함수 사용법｜조건에 맞는 합계와 개수 구하기’를 함께 참고해 보세요.

SUMIF와 SUMIFS의 차이

SUMIF는 한 가지 조건을 기준으로 합계를 구하고, SUMIFS는 여러 조건을 기준으로 합계를 구합니다.

함수	조건 개수	활용 예시
SUMIF	1개	A팀의 전체 주문 금액
SUMIFS	2개 이상	A팀이면서 완료된 주문 금액

COUNTIF와 COUNTIFS의 차이도 같습니다.

함수	조건 개수	활용 예시
COUNTIF	1개	완료된 전체 업무 건수
COUNTIFS	2개 이상	제품 A이면서 완료된 업무 건수

함수 이름 뒤에 붙은 S는 여러 조건을 사용할 수 있다는 의미로 이해하면 쉽습니다.

SUMIFS 함수의 기본 구조

SUMIFS 함수의 기본 구조는 다음과 같습니다.

=SUMIFS(합계 범위,조건 범위1,조건1,조건 범위2,조건2)

각 항목의 의미는 다음과 같습니다.

• 합계 범위: 조건을 모두 만족했을 때 실제로 더할 범위
• 조건 범위1: 첫 번째 조건을 확인할 범위
• 조건1: 첫 번째 범위에서 찾을 조건
• 조건 범위2: 두 번째 조건을 확인할 범위
• 조건2: 두 번째 범위에서 찾을 조건

조건이 더 필요하다면 조건 범위와 조건을 뒤에 계속 추가할 수 있습니다.

=SUMIFS(합계 범위,조건 범위1,조건1,조건 범위2,조건2,조건 범위3,조건3)

여기서 주의할 점은 SUMIF와 SUMIFS의 합계 범위 위치가 다르다는 것입니다.

=SUMIF(조건 범위,조건,합계 범위)

=SUMIFS(합계 범위,조건 범위1,조건1,조건 범위2,조건2)

SUMIF에서는 합계 범위가 마지막에 있지만, SUMIFS에서는 합계 범위를 가장 먼저 입력합니다.

두 함수의 이름이 비슷해 수식의 순서를 혼동하기 쉬우므로 주의해야 합니다.

1. A팀이면서 완료된 주문 금액 합계 구하기

이전 글에서 사용한 주문 내역표를 그대로 활용해 보겠습니다.

표에는 다음 항목이 입력되어 있습니다.

• B열: 날짜
• C열: 담당
• D열: 제품
• E열: 진행 상태
• F열: 주문 금액

A팀의 주문 중 진행 상태가 ‘완료’인 주문 금액만 합산하려면 다음 수식을 사용합니다.

=SUMIFS(F3:F10,C3:C10,"A팀",E3:E10,"완료")

수식의 구조를 나누면 다음과 같습니다.

• F3:F10: 실제로 더할 주문 금액 범위
• C3:C10: 담당 팀을 확인할 범위
• "A팀": 첫 번째 조건
• E3:E10: 진행 상태를 확인할 범위
• "완료": 두 번째 조건

이 수식은 담당이 A팀이면서 동시에 진행 상태가 완료인 행만 찾습니다.

예제 표에서 조건을 만족하는 주문 금액은 다음과 같습니다.

• 850,000원
• 1,500,000원
• 600,000원

따라서 계산 결과는 2,950,000원이 됩니다.

SUMIFS와 COUNTIFS의 조건은 모두 만족해야 한다

SUMIFS와 COUNTIFS에 여러 조건을 입력하면 기본적으로 모든 조건을 동시에 만족하는 행만 계산합니다.

앞의 수식은 다음 두 조건을 모두 만족해야 합니다.

• 담당이 A팀
• 진행 상태가 완료

담당이 A팀이어도 진행 상태가 ‘진행’이라면 합계에 포함되지 않습니다.

반대로 진행 상태가 완료여도 담당이 B팀이나 C팀이라면 포함되지 않습니다.

즉, SUMIFS와 COUNTIFS는 여러 조건을 연결할 때 기본적으로 AND 조건으로 작동한다고 이해하면 됩니다.

COUNTIFS 함수의 기본 구조

COUNTIFS 함수는 여러 조건을 모두 만족하는 행의 개수를 구합니다.

기본 구조는 다음과 같습니다.

=COUNTIFS(조건 범위1,조건1,조건 범위2,조건2)

SUMIFS와 달리 합계 범위가 없습니다.

조건을 만족하는 셀이나 행의 개수만 계산하기 때문입니다.

조건이 세 개라면 다음과 같이 범위와 조건을 한 쌍씩 추가합니다.

=COUNTIFS(조건 범위1,조건1,조건 범위2,조건2,조건 범위3,조건3)

2. 제품 A이면서 완료된 업무 건수 구하기

제품이 ‘제품 A’이면서 진행 상태가 ‘완료’인 업무가 몇 건인지 확인해 보겠습니다.

=COUNTIFS(D3:D10,"제품 A",E3:E10,"완료")

이 수식은 다음 두 조건을 확인합니다.

• D3:D10에서 제품명이 ‘제품 A’인지 확인
• E3:E10에서 진행 상태가 ‘완료’인지 확인

두 조건을 모두 만족하는 행만 개수에 포함됩니다.

예제 표에서는 제품 A이면서 완료된 업무가 3건이므로 결과는 3으로 표시됩니다.

3. 문자 조건과 숫자 조건 함께 사용하기

COUNTIFS에는 문자와 숫자 조건을 함께 사용할 수 있습니다.

예를 들어 제품 B이면서 주문 금액이 100만 원 이상인 주문 건수를 구해 보겠습니다.

=COUNTIFS(D3:D10,"제품 B",F3:F10,">=1000000")

이 수식은 다음 조건을 모두 만족하는 행을 계산합니다.

• 제품명이 ‘제품 B’
• 주문 금액이 100만 원 이상

예제 표에서는 조건에 해당하는 주문 금액이 1,200,000원, 1,100,000원, 1,350,000원이므로 결과는 3건입니다.

숫자와 비교 기호를 함께 조건으로 사용할 때는 다음과 같이 큰따옴표로 감싸야합니다.

조건	의미
">1000000"	100만 원 초과
">=1000000"	100만 원 이상
"<1000000"	100만 원 미만
"<=1000000"	100만 원 이하
"<>1000000"	100만 원이 아닌 값

같은 방법으로 A팀 주문 중 100만 원 이상인 금액만 합산할 수도 있습니다.

=SUMIFS(F3:F10,C3:C10,"A팀",F3:F10,">=1000000")

예제 표에서 조건을 만족하는 금액은 1,500,000원과 1,100,000원이므로 결과는 2,600,000원입니다.

4. 셀에 입력된 값을 여러 조건으로 사용하기

조건을 수식에 직접 입력하지 않고 다른 셀의 값을 참조할 수도 있습니다.

예를 들어 다음과 같이 조건을 입력했다고 가정해 보겠습니다.

• H3: A팀
• I3: 완료

두 셀을 조건으로 사용해 주문 금액을 합산하려면 다음 수식을 입력합니다.

=SUMIFS(F3:F10,C3:C10,H3,E3:E10,I3)

이 수식은 C열에서 H3에 입력된 팀을 찾고, E열에서 I3에 입력된 진행 상태를 찾습니다.

H3을 B팀으로 바꾸거나 I3을 진행으로 바꾸면 수식을 수정하지 않아도 결과가 자동으로 달라집니다.

조건을 자주 변경해 조회해야 하는 업무표에서는 조건을 수식에 직접 넣는 것보다 별도의 셀에 입력하는 방법이 편리합니다.

5. 비교 기호와 셀 주소 함께 사용하기

기준 금액을 셀에 입력하고 그 값을 조건으로 사용할 수도 있습니다.

예를 들어 H5 셀에 기준 금액 1000000이 입력되어 있다면 다음과 같이 사용합니다.

=COUNTIFS(D3:D10,"제품 B",F3:F10,">="&H5)

여기에서 ">="&H5는 H5에 입력된 값 이상이라는 뜻입니다.

비교 기호는 큰따옴표 안에 넣고, 셀 주소는 큰따옴표 밖에서 &로 연결합니다.

잘못된 수식:

=COUNTIFS(D3:D10,"제품 B",F3:F10,">=H5")

올바른 수식:

=COUNTIFS(D3:D10,"제품 B",F3:F10,">="&H5)

">=H5"라고 입력하면 엑셀은 H5를 셀 주소가 아니라 문자로 인식할 수 있습니다.

6. 시작일과 종료일 사이의 합계 구하기

SUMIFS는 특정 기간에 해당하는 금액을 계산할 때도 유용합니다.

예를 들어 시작일이 H5 셀에 입력되어 있고 종료일이 I5 셀에 입력되어 있다면 다음 수식을 사용할 수 있습니다.

=SUMIFS(F3:F10,B3:B10,">="&H5,B3:B10,"<="&I5)

이 수식은 다음 두 조건을 모두 만족하는 주문 금액을 합산합니다.

• 주문 날짜가 H5의 시작일 이상
• 주문 날짜가 I5의 종료일 이하

기간별 매출, 월별 발주 금액, 특정 기간의 비용을 확인할 때 활용할 수 있습니다.

다만 날짜가 실제 날짜가 아닌 문자로 저장되어 있다면 결과가 예상과 다르게 나올 수 있습니다.

날짜가 기본적으로 오른쪽 정렬되어 있는지 확인하고, 필요하다면 셀 서식을 날짜 형식으로 변경합니다.

SUMIFS와 COUNTIFS 사용 시 자주 생기는 오류

SUMIFS의 합계 범위를 마지막에 입력한 경우

SUMIF와 SUMIFS는 합계 범위의 위치가 다릅니다.

잘못된 수식:

=SUMIFS(C3:C10,"A팀",E3:E10,"완료",F3:F10)

올바른 수식:

=SUMIFS(F3:F10,C3:C10,"A팀",E3:E10,"완료")

SUMIFS에서는 실제로 더할 합계 범위를 가장 먼저 입력해야 합니다.

각 범위의 크기가 서로 다른 경우

SUMIFS와 COUNTIFS에 사용하는 각 범위는 시작 행과 끝 행을 맞추는 것이 중요합니다.

올바른 범위:

F3:F10
C3:C10
E3:E10

조건 범위 중 하나만 C3:C9처럼 끝나는 행이 다르면 수식 오류가 발생하거나 원하는 결과를 얻지 못할 수 있습니다.

문자 조건에 큰따옴표가 없는 경우

문자 조건은 큰따옴표로 감싸야합니다.

잘못된 수식:

=COUNTIFS(D3:D10,제품 A,E3:E10,완료)

올바른 수식:

=COUNTIFS(D3:D10,"제품 A",E3:E10,"완료")

비교 기호와 셀 주소를 연결하지 않은 경우

비교 기호와 셀 주소를 함께 사용할 때는 &로 연결해야 합니다.

">="&H5

">=H5"처럼 전체를 큰따옴표 안에 넣지 않도록 주의합니다.

OR 조건으로 잘못 이해한 경우

SUMIFS와 COUNTIFS에 입력된 조건은 기본적으로 모두 만족해야 합니다.

예를 들어 다음 수식은 A팀 또는 완료인 업무를 계산하는 것이 아닙니다.

=COUNTIFS(C3:C10,"A팀",E3:E10,"완료")

이 수식은 A팀이면서 동시에 완료인 업무만 계산합니다.

여러 조건 중 하나만 만족해도 포함하는 OR 방식은 조건이 중복되는지에 따라 수식 구성이 달라질 수 있으므로 별도로 구분해야 합니다.

핵심 내용 정리

SUMIFS는 여러 조건을 모두 만족하는 값의 합계를 구합니다.

=SUMIFS(합계 범위,조건 범위1,조건1,조건 범위2,조건2)

COUNTIFS는 여러 조건을 모두 만족하는 행의 개수를 구합니다.

=COUNTIFS(조건 범위1,조건1,조건 범위2,조건2)

이번 글에서 사용한 대표적인 수식은 다음과 같습니다.

A팀이면서 완료된 주문 금액:

=SUMIFS(F3:F10,C3:C10,"A팀",E3:E10,"완료")

제품 A이면서 완료된 업무 건수:

=COUNTIFS(D3:D10,"제품 A",E3:E10,"완료")

제품 B이면서 100만 원 이상인 주문 건수:

=COUNTIFS(D3:D10,"제품 B",F3:F10,">=1000000")

H3과 I3 셀을 조건으로 사용한 합계:

=SUMIFS(F3:F10,C3:C10,H3,E3:E10,I3)

시작일과 종료일 사이의 주문 금액:

=SUMIFS(F3:F10,B3:B10,">="&H5,B3:B10,"<="&I5)

SUMIFS와 COUNTIFS를 사용할 때는 조건의 개수보다 각 범위와 조건이 올바르게 짝을 이루고 있는지 확인하는 것이 중요합니다.

여러 조건을 함께 계산하는 방법을 익혀두면 팀별 실적, 처리 상태, 금액 기준, 기간별 매출처럼 실제 업무에서 필요한 결과를 빠르게 확인할 수 있습니다.

다음 글에서는 다른 표에서 조건에 맞는 값을 찾아오는 VLOOKUP 함수 사용법을 알아보겠습니다.

참고 자료

• Microsoft Support, SUMIFS 함수
• Microsoft Support, COUNTIFS 함수