WORK

엑셀 SUMIF·COUNTIF 함수 사용법｜조건에 맞는 합계와 개수 구하기

ALIMORY 2026. 9. 8. 07:00

엑셀로 실적표나 주문 내역을 관리하다 보면 전체 합계나 전체 건수보다 특정 조건에 해당하는 결과가 필요한 경우가 많습니다.

예를 들면 다음과 같습니다.

  • A팀의 주문 금액은 모두 얼마인지
  • 완료된 업무는 몇 건인지
  • 주문 금액이 100만 원 이상인 건은 몇 개인지
  • 특정 제품의 매출 합계는 얼마인지

필터를 적용해 직접 확인할 수도 있지만, 조건이나 데이터가 바뀔 때마다 다시 계산해야 한다는 불편함이 있습니다.

이럴 때 사용하는 대표적인 함수가 SUMIF와 COUNTIF입니다.

SUMIF는 조건에 맞는 값의 합계를 구하고, COUNTIF는 조건에 맞는 셀의 개수를 구합니다.

이번 글에서는 두 함수의 차이와 기본 구조부터 문자·숫자 조건, 셀을 조건으로 사용하는 방법까지 알아보겠습니다.

※ 이 글은 Excel 2016을 기준으로 작성했으며, Microsoft 365를 비롯한 이후 버전에서도 같은 방식으로 사용할 수 있습니다.

 

 

IF 함수의 기본 사용법이 궁금하다면 이전 글인 ‘엑셀 IF 함수 사용법｜조건에 따라 결과 자동 표시하기’를 함께 참고해 보세요.

 

SUMIF와 COUNTIF의 차이

두 함수는 모두 지정한 범위에서 조건에 맞는 데이터를 찾습니다.

차이는 조건에 맞는 데이터를 찾은 다음 무엇을 계산하느냐에 있습니다.

함수 계산하는 값 활용 예시
SUMIF 조건에 맞는 값의 합계 A팀의 주문 금액 합계
COUNTIF 조건에 맞는 셀의 개수 완료된 업무 건수

쉽게 말하면 다음과 같습니다.

  • 합계를 구하려면 SUMIF
  • 개수를 구하려면 COUNTIF

IF 함수가 조건에 따라 ‘달성’과 ‘미달’처럼 결과를 표시하는 함수라면, SUMIF와 COUNTIF는 조건에 맞는 여러 데이터를 모아 계산하는 함수입니다.

SUMIF 함수의 기본 구조

SUMIF 함수의 기본 구조는 다음과 같습니다.

=SUMIF(조건을 확인할 범위,조건,합계를 구할 범위)

각 항목의 의미는 다음과 같습니다.

  • 조건을 확인할 범위: 어떤 셀에서 조건을 찾을지 지정
  • 조건: 찾으려는 문자나 숫자
  • 합계를 구할 범위: 조건에 해당할 때 실제로 더할 셀 지정

예를 들어 C3:C10에서 ‘A팀’을 찾고, 해당하는 행의 F3:F10 주문 금액을 더하려면 다음과 같이 입력합니다.

=SUMIF(C3:C10,"A팀",F3:F10)

수식의 구조를 말로 바꾸면 다음과 같습니다.

C3부터 C10까지 확인해서 A팀인 행을 찾고, 해당 행의 F열 주문 금액을 모두 더해 줘.

1. 특정 팀의 주문 금액 합계 구하기

다음과 같이 날짜, 담당, 제품, 진행 상태, 주문 금액이 정리된 표가 있다고 가정해 보겠습니다.

A팀의 주문 금액만 합산하려면 다음 수식을 사용합니다.

=SUMIF(C3:C10,"A팀",F3:F10)

이 수식에서 각 범위의 역할은 다음과 같습니다.

  • C3:C10 : 담당 팀을 확인할 범위
  • "A팀" : 찾으려는 조건
  • F3:F10 : 주문 금액을 더할 범위

A팀에 해당하는 주문 금액이 850,000원, 1,500,000원, 1,100,000원, 600,000원이라면 계산 결과는 4,050,000원이 됩니다.

조건은 수식 안에 직접 입력("A팀")할 수도 있고, 다른 셀에 입력된 값을 참조(H3)할 수도 있습니다.

예제 화면에서는 H3 셀에 ‘A팀’을 입력하고 다음 수식을 사용했습니다.

=SUMIF(C3:C10,H3,F3:F10)

=SUMIF(C3:C10,"A팀",F3:F10)처럼 조건을 수식에 직접 입력한 경우와 계산 결과는 같습니다.

여기에서 가장 중요한 것은 조건 범위와 합계 범위의 행이 서로 대응해야 한다는 점입니다.

예를 들어 조건 범위를 C3:C10으로 지정했다면 합계 범위도 F3:F10처럼 같은 시작 행과 끝 행을 사용하는 것이 좋습니다.

범위의 크기나 위치가 서로 다르면 예상과 다른 결과가 나올 수 있습니다.

합계 범위를 생략할 수 있는 경우

조건을 확인할 범위와 실제로 더할 범위가 같다면 세 번째 항목인 합계 범위를 생략할 수 있습니다.

예를 들어 F3:F10에서 100만 원 이상인 금액만 합산하려면 다음과 같이 입력할 수 있습니다.

=SUMIF(F3:F10,">=1000000")

조건을 확인하는 범위와 더하는 범위가 모두 F3:F10이기 때문에 합계 범위를 다시 입력하지 않아도 됩니다.

반면 담당 팀은 C열에서 확인하고 주문 금액은 F열에서 더하는 경우에는 세 번째 합계 범위를 반드시 지정해야 합니다.

COUNTIF 함수의 기본 구조

COUNTIF 함수는 조건에 맞는 셀의 개수를 구합니다.

기본 구조는 다음과 같습니다.

=COUNTIF(조건을 확인할 범위,조건)

SUMIF와 달리 합계 범위가 필요하지 않습니다.

조건에 맞는 셀이 몇 개인지만 세기 때문입니다.

2. 완료된 업무 건수 구하기

진행 상태가 E3:E10에 입력되어 있고, 그중 ‘완료’인 업무가 몇 개인지 확인하려면 다음 수식을 사용합니다.

=COUNTIF(E3:E10,"완료")

이 수식은 E3부터 E10까지 확인해 ‘완료’라고 입력된 셀의 개수를 계산합니다.

예제 표에서 완료된 업무가 5건이라면 결과는 5로 표시됩니다.

‘완료’라는 조건도 수식에 직접 입력("완료")하는 대신 다른 셀을 참조(H3)할 수 있습니다.

예제 화면에서는 H3 셀에 ‘완료’를 입력하고 다음 수식을 사용했습니다.

=COUNTIF(E3:E10,H3)

=COUNTIF(E3:E10,"완료")와 같은 결과가 표시됩니다.

COUNTIF는 다음과 같은 상황에서 활용할 수 있습니다.

  • 완료된 업무 건수
  • 미입력 항목 개수
  • 특정 담당자의 업무 건수
  • 특정 제품의 주문 횟수
  • 목표 이상을 달성한 항목 개수

3. 숫자 조건 사용하기

COUNTIF에서는 특정 숫자뿐 아니라 ‘이상’, ‘초과’, ‘미만’과 같은 비교 조건도 사용할 수 있습니다.

예를 들어 주문 금액이 100만 원 이상인 건수를 구하려면 다음 수식을 사용합니다.

=COUNTIF(F3:F10,">=1000000")

비교 기호가 들어간 조건은 큰따옴표로 감싸야합니다.

조건 의미
">1000000" 100만 원 초과
">=1000000" 100만 원 이상
"<1000000" 100만 원 미만
"<=1000000" 100만 원 이하
"<>1000000" 100만 원이 아닌 값

다음 수식은 주문 금액이 100만 원을 초과한 건수를 계산합니다.

=COUNTIF(F3:F10,">1000000")

반면 정확히 100만 원인 셀을 찾을 때는 숫자만 입력해도 됩니다.

=COUNTIF(F3:F10,1000000)

4. 셀에 입력된 값을 조건으로 사용하기

앞의 예제 이미지에서 사용한 것처럼, 수식 안에 ‘A팀’이나 100만 원을 직접 입력하지 않고 다른 셀에 입력된 값을 조건으로 사용할 수도 있습니다. 이번에는 이 방법을 조금 더 자세히 알아보겠습니다.

예를 들어 H3 셀에 A팀이 입력되어 있다면 다음과 같이 사용할 수 있습니다.

=SUMIF(C3:C10,H3,F3:F10)

이제 H3의 값을 B팀이나 C팀으로 바꾸면 합계도 자동으로 달라집니다.

수식을 직접 수정하지 않고 조건 셀만 변경하면 되기 때문에 반복해서 조회할 때 편리합니다.

숫자 비교 조건과 셀 주소를 함께 사용할 때는 비교 기호와 셀 주소를 &로 연결합니다.

예를 들어 H5 셀에 기준 금액 1000000이 입력되어 있다면 다음 수식을 사용합니다.

=COUNTIF(F3:F10,">="&H5)

여기에서 ">="&H5는 ‘H5에 입력된 값 이상’이라는 뜻입니다.

비교 기호만 큰따옴표 안에 넣고, 셀 주소는 큰따옴표 밖에서 &로 연결하는 것이 핵심입니다.

이 방식을 이용하면 조건을 선택하거나 입력하는 간단한 조회표를 만들 수 있습니다.

5. 특정 문자가 포함된 셀 찾기

조건이 정확히 일치하지 않아도 특정 문자가 포함된 셀을 찾고 싶을 때는 와일드카드를 사용할 수 있습니다.

대표적인 와일드카드는 "*"와 "?"입니다.

  • * : 글자 수와 관계없이 여러 문자를 대신함
  • ? : 임의의 한 문자를 대신함

예를 들어 D3:D10에서 이름에 ‘A’가 포함된 제품의 개수를 구하려면 다음과 같이 입력합니다.

=COUNTIF(D3:D10,"*A*")

"*A*"는 A의 앞이나 뒤에 다른 문자가 있어도 조건에 포함한다는 뜻입니다.

제품명이 ‘제품 A’, ‘A형 제품’, ‘신형 A 제품’처럼 입력되어 있어도 모두 찾을 수 있습니다.

다음 수식은 D3:D10에서 ‘제품’으로 시작하는 셀의 개수를 구합니다.

=COUNTIF(D3:D10,"제품*")

거래처명이나 제품명의 일부만 기억할 때도 활용할 수 있지만, 비슷한 이름이 많다면 의도하지 않은 항목까지 포함될 수 있으므로 결과를 확인하는 것이 좋습니다.

6. 빈칸과 입력된 셀 개수 구하기

COUNTIF를 사용하면 지정한 범위의 빈칸도 확인할 수 있습니다.

E3:E10에서 비어 있는 셀의 개수를 구하려면 다음 수식을 사용합니다.

=COUNTIF(E3:E10,"")

반대로 값이 입력된 셀의 개수를 구하려면 다음과 같이 입력합니다.

=COUNTIF(E3:E10,"<>")

업무표에서 진행 상태나 담당자가 빠진 항목을 확인할 때 유용합니다.

SUMIF와 COUNTIF 사용 시 자주 생기는 오류

조건에 큰따옴표를 사용하지 않은 경우

문자 조건이나 비교 기호가 들어간 조건은 큰따옴표로 감싸야합니다.

잘못된 수식:

=COUNTIF(E3:E10,완료)

올바른 수식:

=COUNTIF(E3:E10,"완료")

숫자와 비교 기호를 함께 사용할 때도 큰따옴표가 필요합니다.

=COUNTIF(F3:F10,">=1000000")

조건 범위와 합계 범위가 맞지 않는 경우

SUMIF에서는 조건 범위와 합계 범위의 크기와 위치가 서로 대응해야 합니다.

예를 들어 다음처럼 범위의 시작 행과 끝 행을 맞추는 것이 좋습니다.

=SUMIF(C3:C10,"A팀",F3:F10)

조건 범위는 3행부터 10행인데 합계 범위가 4행부터 시작하면 서로 다른 행의 값이 계산될 수 있습니다.

눈에 보이지 않는 공백이 포함된 경우

셀에 ‘완료’라고 보이더라도 앞이나 뒤에 공백이 들어 있으면 다른 문자로 인식될 수 있습니다.

예를 들어 다음 값은 화면상으로 비슷해 보여도 서로 다릅니다.

  • "완료"
  • "완료 "
  • " 완료"

조건과 일치하는 값이 있는데 결과가 0으로 나온다면 불필요한 공백이 포함되어 있는지 확인해야 합니다.

공백이 많다면 이후에 다룰 TRIM 함수를 사용해 정리할 수 있습니다.

필터로 숨긴 행까지 계산되는 경우

SUMIF와 COUNTIF는 필터로 화면에서 숨겨진 행도 지정된 범위에 포함해 계산합니다.

따라서 필터 후 화면에 보이는 데이터만 합계하거나 개수를 구하려는 경우에는 결과가 예상과 다를 수 있습니다.

필터로 표시된 셀만 계산할 때는 이후에 소개할 SUBTOTAL 함수를 사용하는 것이 적합합니다.

조건이 두 개 이상인 경우

SUMIF와 COUNTIF는 기본적으로 한 가지 조건을 기준으로 계산합니다.

예를 들어 다음과 같이 두 가지 조건을 동시에 적용하려면 다른 함수가 필요합니다.

  • A팀이면서 진행 상태가 완료인 주문 금액
  • 제품 A이면서 100만 원 이상인 주문 건수

이럴 때는 SUMIFS와 COUNTIFS 함수를 사용합니다.

핵심 내용 정리

SUMIF는 조건에 맞는 값의 합계를 구합니다.

=SUMIF(조건 범위,조건,합계 범위)

COUNTIF는 조건에 맞는 셀의 개수를 구합니다.

=COUNTIF(조건 범위,조건)

이번 글에서 사용한 대표적인 수식은 다음과 같습니다.

A팀의 주문 금액 합계:

=SUMIF(C3:C10,"A팀",F3:F10)

완료된 업무 건수:

=COUNTIF(E3:E10,"완료")

100만 원 이상인 주문 건수:

=COUNTIF(F3:F10,">=1000000")

H3 셀의 팀을 기준으로 주문 금액 계산:

=SUMIF(C3:C10,H3,F3:F10)

H5 셀의 기준 금액 이상인 주문 건수:

=COUNTIF(F3:F10,">="&H5)

함수의 이름과 수식을 외우는 것보다 조건을 어느 범위에서 확인하고, 어떤 값을 계산할 것인지 구분하는 것이 중요합니다.

SUMIF와 COUNTIF를 익혀두면 실적표, 주문 내역, 일정표, 재고표 등 다양한 업무 자료에서 필요한 합계와 개수를 빠르게 확인할 수 있습니다.

다음 글에서는 조건을 두 개 이상 적용해 합계와 개수를 구하는 SUMIFS와 COUNTIFS 함수 사용법을 알아보겠습니다.

참고 자료